Nejprve si ukážeme použití SW Mathematica jako náhrady tabulek řad, integrálů nebo dif. rovnic

Jde o krátký úvod, více naleznete v odkazech na webové stránce semináře

Integrate[    x^4 Sin[x] ,x]

Pozor, u vícenásobných integrálů záleží na pořadí (pro někoho to je “obráceně”)

HoldForm[Integrate[   1,{x,-1,1} ,{y,-Sqrt[1-x^2],Sqrt[1-x^2]}]]==
Integrate[   1,{x,-1,1} ,{y,-Sqrt[1-x^2],Sqrt[1-x^2]}]
HoldForm[Integrate[   1,{y,-Sqrt[1-x^2],Sqrt[1-x^2]},{x,-1,1}]]==
Integrate[   1,{y,-Sqrt[1-x^2],Sqrt[1-x^2]},{x,-1,1}]

Vždy to můžeme zapsat jako dva integrály

Integrate[
Integrate[    1,{y,-Sqrt[a^2-x^2],Sqrt[a^2-x^2]}],
  {x,-a,a} 
]

Urychlit výpočet a zpřehlednit výsledek lze (příp. je nutno) s pomocí Assumptions->

Integrate[ Exp[-a x^2],{x,-Infinity,+Infinity},Assumptions->a>0]

Potěší, že lze nalézt i součet všelijakých řad, podobně jako u integrace často za použití velmi speciálních funkcí

Sum[ (1+i x)^(-2), {i,1,Infinity}]

Derivace

Takto vypadá obyčejná funkce

f[x]

Potřebujeme to vědět, protože jinak by ji D chápalo jako konstantu

D[f[x],x]
D[f,x]

Podobně druhá derivace

D[f[x],{x,2}]

Také můžeme k označení derivace použít apostrof

D[f[x],x]-f'[x]

Důležitý detail, jako znak rovnosti se používá dvojité rovnítko == , jednoduché = (a to i uprostřed výrazů) znamená přiřazení
Když se spleteme, je většinou potřeba přiřazení odstranit :

Solve[ y=2x,y]

Třeba takto

y=.

Rovnice lze často řešit jak symbolicky, tak numericky
(s detaily se obeznámíme postupně)

Solve[ x^3 - 3 x -1==0,x]
N[%,50](* vypocitej na 50 mist *)
Chop[%] (* odstraň pravděpodobně nulové smetí *)

Některé rovnice nemají řešení v podobě nějakého výrazu ( co s tím ... někdy příště )

Solve[ x Sin[x] -a==0,x]

Takto se řeší obyč. dif. rovnice

DSolve[ f'[x]==f[x],f[x],x]

Přidat můžeme počáteční podmínky

DSolve[ f'[x]==f[x] && f[0]==1,f[x],x]

Nebo dokonce podmínky okrajové

Simplify[ DSolve[ f''[x]==-f[x] && f[-1]==1 && f[1]==1,f[x],x] ]

Další, co se dříve hledalo v tabulkách jsou rozvoje

Series[ Log[(x-a)/(x+a)] , {a,0,14}]

Rozvíjet lze i okolo nekonečna

Series[ Log[(x-a)/(x+a)] , {x,Infinity,14}]

Krátký příklad, jak takové rozvoje pak i namalovat

Table[ Series[ Sin[x],{x,0,n}], {n,1,20,4}];
rozvoje = %//Normal

vsechnyFunkce = Join[ {Sin[x]},rozvoje]; (*středník abychom se schovali výsledek*)

Plot[vsechnyFunkce,{x,-3Pi,3Pi},Frame->True,GridLines->Automatic,PlotRange->{-2,2},PlotStyle->{Dotted,Red,Blue,Green,Orange,Magenta}]

Ještě k derivování

D[ a[t]^2 x, t, NonConstants->x]

D[ a[t]^2 x[t], t]

Takto počítáme gradient:

D[ Sin[ x y], {{x,y}}]

Takto Jakocobián

poSouradnice = { R Cos[ϕ], R Sin[ϕ ]}

mujJacobian = D[ poSouradnice, {{R,ϕ}} ]
MatrixForm[%]

A něco k integrování

Někdy to trvá dlouho, než vzdá symbolickou integraci....

oi = Integrate[  Cos[x] Exp[-1/(1-x^2)], {x,-1,1} ]

N[oi,32]

Někdy je výsledek nečitelný, ale (jako zde) dovoluje další počítání

osni = Integrate[ 1/(1+x+a x^3) ,x]

Plot[ Table[osni,{a,1,4}], {x,-1,2}]

Co to jsou ty # ?

Vlastně jde o zápis funkce, (ta se zde musí vyhodnotit, aby se zjistilo, kolik je výsledek)

mf1[x_] = x Sin[1/x]   (*Neni ve skutecnosti tak uplne funkce*)
mf2=Function[x,x Sin[1/x]]
mf3=# Sin[1/#]&

Plot[ mf3[s],{s,0,1/2},PlotTheme->"Scientific"]