Greenova funkce standardní metodou

Operátor

L[g_[z_]]=-g''[z]

Hraniční podmínky

BC={u[0]==0,u[1]==0}

G[x_,y_]=GreenFunction[Flatten[{L[u[x]],BC}],u[x],{x,0,1},y]

Plot3D[G[x,y],{x,0,1},{y,0,1}]

Greenova funkce pomocí vlastních funkcí

num=10   (* kolik vlastních funkcí použít*)

{values,functions}=DEigensystem[{L[u[x]],DirichletCondition[u[x]==0,True]},u[x],{x,0,1},num,Method->"Normalize"]

{values[[3]],functions[[3]]}

DiscretePlot[values[[k]],{k,1,num}]

plotfunctions=functions[[1;;Min[8,num]]]

Plot[plotfunctions,{x,0,1}]

starfunctions=functions/.x->y

EG[x_,y_]=Sum[starfunctions[[n]]*functions[[n]]/values[[n]],{n,1,num}]

Plot3D[EG[x,y],{x,0,1},{y,0,1}]

Symbolické sečtení rozkladu

EGterm[n_]=2*Sin[n*π*x]*Sin[n*π*y]/(n^2*π^2)

Sum[EGterm[k],{k,1,Infinity}]

SymbSum=Assuming[{0<x<1,0<y<1},Sum[EGterm[k],{k,1,Infinity}]]

G[x,y]-SymbSum//FullSimplify